Itunes Soittolistojen luonti kansiosta

[Musgrapha]

Olen siirtymästä PC:stä Macciin. Mulla on vanhalla koneella kerättynä 120 gigatavua musiikkia. Koska kaikki kappaleet eivät sisällä oikein merkittyjä id-tageja, olen järjestänyt musiikin kansioihin jotka ovat muotoa "Artisti - Levy". Kun tällaisen kansion raahaa itunesiin, se tekee automaattisesti soittolistan oikealla nimellä. En kuitenkaan haluaisi raahata nyt kutakin kansiota ERIKSEEN soittolistat-kohtaan.

Löytyisikö keltään tiedossa ratkaisua tai ohjelmaa joka osaisi lisätä kertaheitolla koko kirjaston iTunesiin soittolistoiksi?

Olen hyvin tietoinen että iTunes jörjestelee oman logiikkansa mukaisesti kappaleet ja artistit järjestykseen mutta id-tagiongelman vuoksi haluaisin järjestää musiikin omalla tavallani.

Kiitos!

[K4]

Melko turhaa on iTunesin kanssa sohlata jos kerran väkisin haluat pitää kipaleet järjestyksessä käsipelillä ja tiedoston/kansion nimien perusteella. Koko touhu tunesissa kun perustuu nimenomaan niihin ID-tageihin. Ehkä joku kokonaan muu soitin olisi parempi tuohon tarkoitukseen?

[Sälli]

Mä suosittelisin skriptiä, joka käy ton sun kansiohierarkian läpi, lisää tiedostot iTunesiin ja parsii artistin ja albumin nimet kansioiden nimistä lisäten ne musiikkitiedostojen tageihin. Näin saat asian tehtyä kerralla "oikein". Tohon on varmaan valmiitakin ohjelmia olemassa, joita voi koittaa ettiä VersionTrackeristä tai MacUpdatesta. Jos ei löydy, AppleScriptillä toi onnistunee suht simppelisti, ja voin tarvittaessa jeesata skriptin teossa.

[Sälli]

Homma jäi mietityttämään sen verran, että oli pakko kokeilla onnistuuko se tosiaan niin helposti kuin ajattelin. Eli tässä jonkinlainen skripti. Virheensietoa ei ole, joten oletuksista kannattaa pitää huoli, eli:

Oletan, että sulla on siis musiikkikirjasto järjestettynä osapuilleen näin:

Koodi: Valitse kaikki

Musat
  Artisti 1 - Albumi 1
    Biisi 1.mp3
    Biisi 2.mp3
  Artisti 1 - Albumi 2
    Biisi 1.mp3
    Biisi 2.mp3
  Artisti 2 - Albumi 1
    Biisi 1.mp3
    Biisi 2.mp3

Eli yksi pääkansio, jonka alla noi kaikki "Artisti - Albumi" kansiot, joiden sisällä kappaleet. Ja artistin ja albumin erottaa siis aina nämä kolme merkkiä " - ". Jos noita on kansion nimessä useampia, ne menevät osaksi albumin nimeä ja artisti katkeaa siis kesken. Näiden korjaaminen jälkikäteen käsipelillä ei liene iso homma. Kappaleiden nimet muodostetaan tiputtamalla tiedoston nimestä neljä viimeistä merkkiä pois (".mp3", tms).

Ja tässä itse skripti, alussa se siis kysyy ton musiikkikirjastokansiosi sijaintia, jonka sisällä nuo "Artisti - Albumi" -kansiot ovat. AppleScript on suhteellisen helppolukuista, ja kannattaa ennen suoritusta katsoa, että mitä skripti tekee, koska mitään virheensietoa tai vahvistusten kyselyjä ei siis ole.

Koodi: Valitse kaikki

set kansio to choose folder

set od to text item delimiters of AppleScript
set text item delimiters of AppleScript to {" - "}
tell application "Finder"
	set alakansiot to every folder of kansio
	repeat with alakansio in alakansiot
		set levy to name of alakansio
		set artisti to text item 1 of levy as text
		set albumi to text items 2 thru -1 of levy as text
		set tiedostot to every file of alakansio
		repeat with tiedosto in tiedostot
			set polku to tiedosto as alias
			set nimi to name of polku
			set kappale to text 1 thru -5 of nimi as text
			tell application "iTunes"
				set raita to add polku
				set artist of raita to artisti
				set album of raita to albumi
				set name of raita to kappale
			end tell
		end repeat
	end repeat
end tell
set text item delimiters of AppleScript to od

[gramdel]

Esim. mp3 rage, tai se taitaa nykyään olla mediarage, tekee automaattisesti tagit vaikkapa sitten kansiorakenteen ja fileen nimen perusteella.

http://www.chaoticsoftware.com/

Muitakin varmasti löytyy, mutta tuo on mainio.

/---
ap

[Musgrapha]

Jeps. Kiitos vastauksista, siellä on paljon hyvää.

Vaan; mulla on muitakin syitä tehdä tää homma soittolistojen kautta.

1. Saan valittua kätsästi levyt jotka kulloinkin haluan ipodiini (joka ei siis vedä sitä 120 gigaa).

2. Omat kokoelmat tulee joka tapauksessa tehtyä soittolistoihin, ja tällöinkin koko musiikkikirjasto löytyy soittolistoista. Se on vaan mulle mieluisin tapa selata musiikkia.

3. Kansiot sisältävät paikoin useammasta levystä koottuja settejä. En halua sekoittaa näiden kansioiden sisällä mahdollisesti oikein id-tägättyjä tiedostoja (Tuloksena saattaisi olla jotain tyyliin "Parhaat Polkkasuosikit - 1" id-tagissa).

Ja satun tykkäämään iTunesin käyttöliittymästä nyt kun olen tottunut siihen - tätä handicappia lukuunottamatta.

[Sälli]

mulla on muitakin syitä tehdä tää homma soittolistojen kautta.

Tällä hoitunee:

Koodi: Valitse kaikki

set kansio to choose folder

tell application "Finder"
	set alakansiot to every folder of kansio
	repeat with alakansio in alakansiot
		set levy to name of alakansio
		set tiedostot to every file of alakansio
		set polut to {}
		repeat with tiedosto in tiedostot
			set polut to polut & {tiedosto as alias}
		end repeat
		tell application "iTunes"
			set soittolista to make new playlist with properties {name:levy}
			add polut to soittolista
		end tell
	end repeat
end tell