Miten eroon ._ tiedostoista?

[Kimble]

Tässä koittanut löytää ratkaisua jo muutaman päivän, oletteko te törmännyt tähän.

1. Minulla on Samba palvelin verkossa. Sieltä on jaossa levyjako nimeltä arkisto.
2. Mounttaan levyn Macciin (10.5.5 / 9F33) sellaisilla tunnuksilla, joilla on lupa kirjoittaa tuohon levyjakoon.
3. Nappaan Finderilla kasan tiedostoja ja raahaan ne tuolle arkisto-levylle, kopiointi alkaa.
4. Kun samaan aikaan katson levyjaon tiedostoja Linux-koneella niin näen että jaettuun hakemistoon luodaan jokaista kopioitavaa tiedostoa kohden ._ tiedosto ja 0 bytes mittainen "ghost" itse siirrettävästä tiedostosta.

Miten viritän OSX:n sellaiseksi ettei noita ._ tiedostoja luoda verkkolevylle laisinkaan?

Tiedän että ne ._ tiedostot ovat jotain Macin fork-tiedostoja, tietoja sovelluksesta, jne. Ei kiinnosta vähäänkään, haluan vain sen itse tiedoston talteen, ilman mitään hienosteluja ja kikkailuja.

[freemem]

support.apple.com sanoo seuraavasti:

To configure a Mac OS X user account so that .DS_Store files are not created when interacting with a remote file server using the Finder, follow the steps below.
Note: This will affect the user's interactions with SMB/CIFS, AFP, NFS, and WebDAV servers.

Open the Terminal.
Type:
defaults write com.apple.desktopservices DSDontWriteNetworkStores true
Press Return.
Restart the computer.

[AppleFarmer]

Verkkolevyltä DSStore-tiedostojen luomisen saa pois päältä seuraavalla tavalla.

1. Avaa Ohjelmat / Lisäohjelmat >> Pääte (Terminal).
2. Kirjoita sinne defaults write com.apple.desktopservices DSDontWriteNetworkStores true ja paina enteriä.

Edit: Hidas

[Kimble]

Verkkolevyltä DSStore-tiedostojen luomisen saa pois päältä seuraavalla tavalla.

1. Avaa Ohjelmat / Lisäohjelmat >> Pääte (Terminal).
2. Kirjoita sinne defaults write com.apple.desktopservices DSDontWriteNetworkStores true ja paina enteriä.

Edit: Hidas

Vahvistakaa vielä, poistaako "defaults write com.apple.desktopservices DSDontWriteNetworkStores true" asetus sekä ._ tiedostojen että .DStore tiedostojen luonnin. Näin tämän jutun monta kertaa mutta ohitin sen siksi että luulen sen koskevan vain .DStore tiedostoa?

Ja suurkiitokset nopeista vastauksista.

[Kimble]

Niin kuin epäilin tuo asetus ei pistä ._ tiedostojen muodostusta pois päältä. Se kyllä estää itse .DStore tiedostojen luomiksen verkkolevylle.

Eli ongelma on edelleen auki, jos joku tietää miten kytken päältä ._ tiedostojen luomisen niin saa papukaijamerkin jos kertoo siitä tänne!

[Aaaron]

Jos se purkki on Linux, niin ota Samba pois ja käytä sftp:tä tai viritä AFP-jako. SMB on kaiken lisäksi hidas.

http://www.kremalicious.com/2008/06/ubu ... ne-volume/

[Kimble]

Jos se purkki on Linux, niin ota Samba pois ja käytä sftp:tä tai viritä AFP-jako. SMB on kaiken lisäksi hidas.

Ihan mielenkiintoista mutta tässä tapauksessa ei lähdetä yhden clientin takia muuttelemaan serveripäätä. Taitaa olla niin Mac pitää tuomita ei-yhteensopivaksi Samban kanssa.

[morbusg]

Eikös nuo ._ -tiedostot ole lukko-tiedostoja?

[mirko]

Samba se Mac OS X:nkin päässä on.

Ongelma on yleensä paikallistettavissa ihan tiettyihin vanhoihin tiedostomuotoihin ja niitä käyttäviin ohjelmiin. Osasta ohjelmista tiedostot saa tallennettua niin, että niihin ei tule resurssihaarukkaa (sitä resource forkia, josta jo olitkin jostain lukenut).

Eri ohjelmien lukko-, väliaikais- ja piilotiedostot ovat ihan oma juttu. Osa niistä alkaa pisteellä, mutta harvemmin (jos juuri koskaan) piste-alaviivalla.

[supersankari]

Onkohan konstia saada Mac ympäristössä poistettua ._alkuiset haamutiedostot, jotka tulevat aina esiin Windows koneilla?
Jos kopsaan USB tikulle tai suoraan Windows palvelimelle mitä tahansa Macilla luotua, Windows koneella näkyy aina tuplatiedostot ja ._haamutiedostot eivät aukea mihinkään.


PS: Kerran kollega sai valokuvaamosta vedokset myös näistä tiedostoista. Olivat melko mielenkiintoisen näköisiä valokuvia.

[tyttone]

En oo varma onko varma mistä puhut, mutta mulla tuli yhdessä vaiheessa ds-tiedostot näkyviin, ja sain ne tällä ohjeella pois
.localized and .DS_store files removing
terminal and put this there:
defaults write com.apple.finder AppleShowAllFiles False; killall Finder
and enter!

Olisi muuten myös kiva tietää millä saa näkyviin tikuissa olevat nuo näkymättömät tiedostot näkyviin maceilla. Muistan kun vuonna sata vaihtelin tiedostoja windowssista mäkille ja piti aina windowsin kautta poistella niitä että sain lisää tilaa.

[Sherukka]

PS: Kerran kollega sai valokuvaamosta vedokset myös näistä tiedostoista. Olivat melko mielenkiintoisen näköisiä valokuvia.

Hehe! Olipa ammatitaitoista väkeä!
Onko tähän tyylikkäämpää ratkaisua eli saako levykohtaisesti valita luodaanko näitä OS X:n käyttämiä tiedostoja?

[gramdel]

En oo varma onko varma mistä puhut, mutta mulla tuli yhdessä vaiheessa ds-tiedostot näkyviin, ja sain ne tällä ohjeella pois
.localized and .DS_store files removing
terminal and put this there:
defaults write com.apple.finder AppleShowAllFiles False; killall Finder
and enter!

Varmaan ihan tätä ei etsitty, vaan sitä, miten saisi noiden piilotiedostojen luomisen estettyä. Verkkolevyille saa ainakin .DS_store tiedostojen tekemisen estettyä jotensakin noin http://www.macosxhints.com/article.php? ... 0300463515 usb tikuista en mene vannomaan, mutta vähän luulen että ei onnistu.

Edit: Jonkinlainen purkkaratkaisu tuli näköjään vastaan, http://www.macupdate.com/info.php/id/16996 eli ohjelma joka poistaa piilotiedostot ennen ulkoisen aseman/tikun ejektointia. Ei käyttökokemuksia.

/---
ap

[tyttone]

En oo varma onko varma mistä puhut, mutta mulla tuli yhdessä vaiheessa ds-tiedostot näkyviin, ja sain ne tällä ohjeella pois
.localized and .DS_store files removing
terminal and put this there:
defaults write com.apple.finder AppleShowAllFiles False; killall Finder
and enter!

Varmaan ihan tätä ei etsitty, vaan sitä, miten saisi noiden piilotiedostojen luomisen estettyä. Verkkolevyille saa ainakin .DS_store tiedostojen tekemisen estettyä jotensakin noin http://www.macosxhints.com/article.php? ... 0300463515 usb tikuista en mene vannomaan, mutta vähän luulen että ei onnistu.

/---
ap

nii vähän arvelinki mutta aina voi koittaa

[mirko]

Onkohan konstia saada Mac ympäristössä poistettua ._alkuiset haamutiedostot, jotka tulevat aina esiin Windows koneilla?

Yhdistetty tähän viimeisimpään ketjuun samasta aiheesta. Hakusanalla DSDontWriteNetworkStores löytyy monta muutakin ketjua, joissa käsitellään myös ._-alkuisia tiedostoja. Aiheesta on nyt myös lyhyt kooste wikissä sivulla, jota saa vapaasti täydentää:

http://hopeinenomena.net/wiki/piilotiedostot

[trosberg]

Onkohan konstia saada Mac ympäristössä poistettua ._alkuiset haamutiedostot, jotka tulevat aina esiin Windows koneilla?
Jos kopsaan USB tikulle tai suoraan Windows palvelimelle mitä tahansa Macilla luotua, Windows koneella näkyy aina tuplatiedostot ja ._haamutiedostot eivät aukea mihinkään.

Palaan vanhaan ketjuun, kun nyt Windowsin ja Macin välillä liikkuvalta muistikortilta aina löytyy jokunen näkymätön tiedosto. Supersankarille en osaa vastata, tuntuu että Macin Photoshop luo kaikilla tallennusasetuksillansa resurssihaarukan. Jos käyttää psd-tiedostomuotoa.

Tässä skripti jonka kirjoitin piilotiedostojen käsittelemiseksi. Ohjelma RBrowser http://www.rbrowser.com/ on parempi, tämä on harjoitelma. Tallenna Skriptieditorilla ohjelmaksi.

Huomio. Piilotiedostojen luomiseen on syynsä. Älä puutu näkymättömään tiedostoon, ellet ole selvittänyt mikä se on. Tuomas

Koodi: Valitse kaikki

(*
A script to show some invisible files (those beginning with ".") in a folder. 
An option is given to make selected files visible in Finder.
To examine invisible files there are better tools, 
see <http://forums.macosxhints.com/showthread.php?t=80720> for example.
The script also allows to delete  ._ files of Mac (resource forks) on mounted Windows disks,
and .DS_Store files of Finder (window view settings etc.) as well.
Tested with Mac OS X 10.4.
Tuomas Rosberg, Hämeenlinna, Finland, 2009
*)

property aName : ""
property aPath : ""

on open (x) -- when launched by dropping something on this applet
	tell application "Finder"
		set x to first item in x -- something dragged'n'dropped is always a list.
		set s to properties of x
		if class in s is in {folder, disk} then
			set aName to name of x
			set aPath to POSIX path of x
			my selectInvisibles()
		else -- a file was dropped, not a folder or disk
			run me -- runs the run block below
		end if
	end tell
end open
----
on run -- when launched by double clicking
	set x to choose folder with prompt "Please choose a folder to find if there are invisible files inside."
	tell application "System Events"
		set aName to name of x
		set aPath to POSIX path of x
	end tell
	my selectInvisibles()
end run
----
on selectInvisibles()
	set selected to {}
	display dialog ¬
		"The folder selected is '" & aName & "'" & return & return & ¬
		"Find invisible files in it for further processing" buttons {"Cancel", "Find"} default button 2 with icon note
	set l to do shell script "ls -A " & "'" & aPath & "'"
	set tid to AppleScript's text item delimiters
	set AppleScript's text item delimiters to return
	set l to text items in l as list
	set AppleScript's text item delimiters to tid
	set aList to {}
	repeat with i in l
		set t to contents of i as string
		if first character in t is "." then -- it belongs to invisible items
			set aList to aList & i
		end if
	end repeat
	set selected to choose from list aList with prompt "Please select invisible files." with multiple selections allowed
	if selected is not {} then -- there are invisibles selected
		my process(selected)
	end if
end selectInvisibles
----
on process(selected)
	repeat with i in selected
		if i contains ".DS_Store" then
			display dialog ¬
				"A '.DS_Store file' contains " & return & ¬
				"window view info of the Finder." & return & ¬
				"In 10.4 the Spotlight comments, too." buttons {"Delete", "Skip"} default button 2
			if button returned of result is "Delete" then
				do shell script "rm -f " & "'" & aPath & "/" & i & "'"
			end if
		else if i contains "._" then
			set fileName to (characters 3 through -1 of i) as string
			display dialog ¬
				"'" & i & "' contains the resource " & return & ¬
				"fork of '" & fileName & "' on file" & return & ¬
				"systems other than Apple HFS." & return & ¬
				" Removing it may harm the file." buttons {"Delete", "Skip"} default button 2 with icon 2
			if button returned of result is "Delete" then
				do shell script "rm -f " & "'" & aPath & "/" & i & "'"
			end if
		else if i contains ".Trashes" then
			display dialog ¬
				"Mac folder '.Trashes' holds " & return & ¬
				"removed files. You may " & return & ¬
				"want to delete it on" & return & ¬
				"removable Windows media." & return & ¬
				"Check its contents first!" buttons {"Delete", "Skip"} default button 2 with icon 2
			if button returned of result is "Delete" then
				set f to (POSIX file aPath) as alias
				tell application "Finder"
					if f is ejectable then -- the Trash is on a removable media
						do shell script "rm -fR " & "'" & aPath & "/" & i & "'"
					end if
				end tell
			end if
		else -- an invisible file not belonging to above classes
			display dialog ¬
				"Do you want to make " & return & ¬
				"'" & i & "' visible in Finder?" buttons {"Yes", "No"} default button 2
			if button returned of result is "Yes" then
				set newName to (characters 2 through -1 of i) as string
				set oldPath to "'" & aPath & "/" & i & "'"
				set newPath to "'" & aPath & "/" & newName & "'"
				do shell script "mv " & oldPath & " " & newPath
				display dialog ¬
					"To make the file invisible again, rename it (in Terminal, with mv) with a starting '.'" buttons "Quit" default button 1
			end if
		end if
	end repeat
	tell application "Finder"
		activate
		try
			open (POSIX file aPath) as alias
		end try
	end tell
end process