iSync automaattisesti

[Coltrane]

Rupesi kyllästyttämään Macbookin ja kännykän kalenterin synkkaaminen ja ajattelin, että sen voisi automatisoida vaikka joka ilta tehtäväksi jollain pikku skriptillä.

Netistä löysin tällaisen pätkän, joka tuntui toimivan ihan hyvin:

Koodi: Valitse kaikki

tell application "iSync"
	activate
	synchronize
	repeat until syncing is false
		delay 1
	end repeat
	quit
end tell

Tallensin tuon kotihakemistoon skriptiksi. Mitä seuraavaksi? Miten saan tuon ajettavaksi vaikka joka ilta tiettyyn kellonaikaan?

[anttti]

Cronilla (Unix-työkalu, oletuksena mukana myös OSX:ssä) saat ajastettua: http://www.macosxhints.com/article.php? ... 0700163714.

[nobu178]

Jos koneesi käyttis on Leopard, suosittelen launchd:n käyttöä (Tiikerilläkin pitäisi toimia, mutta oli joskus aiemmin bugeja).

Voit tehdä tosta AppleScript-pätkästä Automatorilla ohjelman, jonka annat launchd:n käynnistettäväksi tietyn ajan välein. Lingon on todella kätevä ohjelma tämän tekemiseksi.

[Goldseller_one]

Kirjoitin aiheesta ohjeet toisella kotimaisella kielellä: http://miikkavarri.wordpress.com/2009/0 ... attiseksi/

Ohjeesas käytetään pelkästään Terminaalia ja seuraavaa komentoa:

Koodi: Valitse kaikki

27 * * * * osascript -e 'tell application "iSync" to synchronize'

[harriba]

Kirjoitin aiheesta ohjeet toisella kotimaisella kielellä: http://miikkavarri.wordpress.com/2009/0 ... attiseksi/

Ohjeesas käytetään pelkästään Terminaalia ja seuraavaa komentoa:

Koodi: Valitse kaikki

27 * * * * osascript -e 'tell application "iSync" to synchronize'

HIljattain mulla oli iPhone huollossa joten ajelin vanhalla Nokialla. Yllättävää kyllä, näytti siltä että iSync ajeli puhelinsyncin aina kun MobileMe synkkasi. Tuo tapahtui ainakin kun käsin synkkasin MobileMe:n. Kiva feature.

[Finx]

Ja tuohon vielä jos haluaa että bluetooth menee päälle ja pois automaattisesti löytyi ohje:

After some poking around I've written a small command-line utility which uses private APIs in the IOBluetooth framework to switch Bluetooth on and off.
Download the utility and use the following modified script to sync like this article explains:

Koodi: Valitse kaikki

property blueutilPath : "/usr/local/bin/blueutil"


-- Check the current bluetooth status and turn it on if necessary.
set btWasOn to true
if execBlueutil("status") ends with "off" then
	set btWasOn to false
	execBlueutil("on")
end if

-- Do the sync and wait for it to finish
tell application "iSync"
	if not (synchronize) then
		display dialog "Failed to start sync"
	else
		repeat while (syncing is true)
			delay 5
		end repeat
		set syncStatus to sync status
		
		if syncStatus = 2 then
			-- Success
			quit
		else
			if syncStatus = 3 then
				set syncStatus to "completed with warnings"
			else if syncStatus = 4 then
				set syncStatus to "completed with errors"
			else if syncStatus = 5 then
				set syncStatus to "last sync cancelled"
			else if syncStatus = 6 then
				set syncStatus to "last sync failed to complete"
			else if syncStatus = 7 then
				set syncStatus to "never synced"
			end if
			display dialog "Sync completed: " & syncStatus
		end if
	end if
end tell


-- Set the bluetooth status to what it was before.
if not btWasOn then execBlueutil("off")


on execBlueutil(command)
	set res to do shell script blueutilPath & " " & command
	if res contains "Error" then
		display dialog res
		quit
	end if
	return res
end execBlueutil

blueutilin voi ladata täältä

Eli vielä rautalangasta:
1. asenna blueutil ohjeiden mukaisesti
2. tee ylläolevasta scriptistä tiedosto: ~/bin/isync
3. tee scriptistä ajettava:

Koodi: Valitse kaikki

chmod +x ~/bin/isync

4.

Koodi: Valitse kaikki

crontab -e

5. kirjoitusmodeen:

Koodi: Valitse kaikki

i

6. lisää esim. rivi (joka ilta klo 22):

Koodi: Valitse kaikki

0 22 * * * osascript ~/bin/isync

7. paina esc
8. poistu crontabista tallentamalla:

Koodi: Valitse kaikki

:wq